; ------------------------------------------------------;
; IdleScript v. 0.7 final                               ;
; ======================================================;
; • Jag kommer inte uppdatera detta script, även om     ;
;   det inte skulle funka alls. (Det funkar om du       ;
;   inte ändrar på det... Jag har testat.)              ;
; • #kanal är kanalen som scriptet ska användas i,      ;
;   alltså där idlare ska kunna skriva !idle            ;
; • Kommandon är !idle [kanal] för att dra in boten     ;
;   och !stopidle [kanal] för att dra ut boten.         ;
;                                                       ;
; © 2005 Jocke "Firetech" Andersson                     ;
;                                                       ;
; NOTE: Jag tycker detta scriptet är lamt, mycket lamt. ;
;       (Använd fishbot istället.)                      ;
;-------------------------------------------------------;


on *:TEXT:!idle *:#kanal: {
  if ($me !ison $$2) {
    if (!$ini(idlescript.ini,IdlerChans,$nick)) {
      set -u120 %idle. $+ $$2 $+ .requester $nick
      notice $nick Joinar $$2 för kontrollering.
      join $$2
    }
    else {
      notice $nick Fel: Du är redan registrerad att ha idlebot i $readini(idlescript.ini,IdlerChans,$nick)
    }
  }
  else {
    notice $nick Fel: Jag är redan i $$2
  }
}

on *:TEXT:!stopidle *:#kanal: {
  if ($me ison $$2) {
    if (($readini(idlescript.ini,IdlerChans,$nick) == $$2) || ($timer(idlejoincheck. $+ $$2))) {
      if ($timer(idlejoincheck. $+ $$2)) {
        .timeridlejoincheck. $+ $$2 off
      }
      part $$2 Personen som requestat mig avslutade samarbetet.
      notice $nick Jag ska nu ha gått ur $$2
      remini idlescript.ini IdlerChans $nick
    }
    else {
      notice $nick Fel: Det var inte du som requestade mig till $$2
    }
  }
  else {
    notice $nick Fel: Jag är inte i $$2
  }
}

on *:JOIN:#: {
  if ($nick == $me) {
    .timeridlejoincheck. $+ $chan 1 2 /idlejoincheck $chan
  }
}

alias idlejoincheck {
  if (%idle. [ $+ [ $$1 ] $+ ] .requester) {
    if (%idle. [ $+ [ $$1 ] $+ ] .requester isop $$1) {
      writeini -n idlescript.ini IdlerChans %idle. [ $+ [ $$1 ] $+ ] .requester $$1 
      notice %idle. [ $+ [ $$1 ] $+ ] .requester Ansökan godkänd. $me kommer stanna i $$1 tills du försvinner ur #kanal $+ .
    }
    else {
      part $$1 Felaktig ansökan.
      notice %idle. [ $+ [ $$1 ] $+ ] .requester Fel: Du måste ha op i kanalen du requestar idlebot för!
    }
  }
  elseif (%idle. [ $+ [ $$1 ] $+ ] .check) {
    if (%idle. [ $+ [ $$1 ] $+ ] .check !isop $$1) {
      part $$1 Personen som requestat mig följer inte längre kriterierna.
      remini idlescript.ini IdlerChans %idle. [ $+ [ $$1 ] $+ ] .check
    }
  }
  unset %idle. $+ $$1 $+ .*
}    

on *:NICK: {
  if ($ini(idlescript.ini,IdlerChans,$nick)) {
    writeini -n idlescript.ini IdlerChans $newnick $readini(idlescript.ini,IdlerChans,$nick)
    remini idlescript.ini IdlerChans $nick
  }
}

on *:PART:#: {
  if ($ini(idlescript.ini,IdlerChans,$nick)) {
    if (($chan == #kanal) || ($chan == $readini(idlescript.ini,IdlerChans,$nick)))  {
      part $readini(idlescript.ini,IdlerChans,$nick) Personen som requestat mig partade vår/er kanal.
      remini idlescript.ini IdlerChans $nick 
    }
  }
}

on *:KICK:#: {
  if ($ini(idlescript.ini,IdlerChans,$knick)) {
    if (($chan == #kanal) || ($chan == $readini(idlescript.ini,IdlerChans,$knick)))  {
      part $readini(idlescript.ini,IdlerChans,$knick) Personen som requestat mig blev kickad ur vår/er kanal.
      remini idlescript.ini IdlerChans $knick 
    }
  }
}

on *:DEOP:#: {
  if ($ini(idlescript.ini,IdlerChans,$opnick)) {
    if ($chan == $gettok($readini(idlescript.ini,IdlerChans,$opnick),1,32))  {
      part $chan Personen som requestat mig blev deopad i er kanal.
      remini idlescript.ini IdlerChans $opnick 
    }
  }
}

on *:QUIT: {
  if ($ini(idlescript.ini,IdlerChans,$nick)) {
    part $readini(idlescript.ini,IdlerChans,$nick) Personen som requestat mig quitade.
    remini idlescript.ini IdlerChans $nick 
  }
}

on *:CONNECT: {
  var %nc = $ini(idlescript.ini,IdlerChans,0), %i = 1, %nick, %chan
  while (%i <= %nc) {
    %nick = $ini(idlescript.ini,IdlerChans,%i)
    %chan = $readini(idlescript.ini,IdlerChans,$ini(idlescript.ini,IdlerChans,%i))
    if (%nick ison #kanal) {
      set -u120 %idle. $+ %chan $+ .check %nick
      join %chan
    }
    else {
      remini idlescript.ini IdlerChans %nick
    }
    inc %i
  }
}